AJAX实例应用初体验：自动保存草稿

　　最后是autosave.asp，用于在后台保存草稿：

　　程序代码：

<%@LANGUAGE="VBscript" CODEPAGE="65001"%>

<% Option Explicit %>

<%

' 语言为VBScript，编码为UTF-8，要求变量声明

' 出现错误则忽略，继续执行

On Error Resume Next

' 定义一些变量

Dim PostContent,memName,action,objStream

' 获取操作，是保存草稿还是恢复草稿

action=Request.Form("action")

' 获取用户名

memName=Request.Form("memname")

' 获取草稿内容

PostContent=Request.Form("postcontent")

IF action="restore" Then

    ' 恢复草稿，如果用户名不为空则进行恢复操作

    IF memName<>Empty Then

        ' 使用 ADODB.Stream 来进行文件操作

        Set objStream = Server.CreateObject("ADODB.Stream")

        With objStream

            .Type = 2

            .Mode = 3

            .Open

            ' 文件名为 autosave_ + 用户名 + .txt

            .LoadFromFile(Server.MapPath("autosave_"&memName&".txt"))

            .Charset = "utf-8"

            '.Position = 0

            PostContent = .ReadText()

            .Close

        End With

        Set objStream = NoThing

        ' 输出草稿

        IF PostContent<>"" Then Response.Write(PostContent)

    End IF

Else

    ' 保存草稿，如果草稿内容和用户名均不为空则进行保存操作

    IF PostContent<>Empty AND memName<>Empty Then

        ' 使用 ADODB.Stream 来进行文件操作

        Set objStream = Server.CreateObject("ADODB.Stream")

        With objStream

            .Type = 2

            .Mode = 3

            .Open

            .Charset = "utf-8"

            .Position = objStream.Size

            .WriteText= PostContent

            .SaveToFile Server.MapPath("autosave_"&memName&".txt"),2

            .Close

        End With

        Set objStream = NoThing

        ' 输出保存是否成功信息

        If Err.Number=0 then

            Response.Write("最后于 "&Now()&" 自动保存成功")

        Else

            Response.Write("最后于 "&Now()&" 自动保存失败，错误号："&Err.Number&"，错误描述："&Err.Dscription)

        End If

    End IF

End IF

%>

　　至此，AJAX草稿自动保存完成了。

　　（原文：http://www.xujiwei.cn/blog/blogview.asp?logID=541）

【深 度 阅 读】 相 关 文 章

AJAX实例入门

70个流行的AJAX应用的演示和源码下载

AJAX+jsp无刷新验证码实例

经典收藏：Ajax学习网址大全